てか、いつもの仕事の感覚で動画作ったら、ニコニコ動画での諸々の制限がきつくて文字がつぶれちゃった～。

てことで、こっちにも解説必要だね。

stage.scaleMode = StageScaleMode.NO_SCALE;

Multitouch.inputMode = MultitouchInputMode.GESTURE;

test_mc.addEventListener(TransformGestureEvent.GESTURE_ROTATE , rotateFunc);
test_mc.addEventListener(TransformGestureEvent.GESTURE_ZOOM , zoomFunc);


function rotateFunc(e:TransformGestureEvent):void{
    test_mc.rotation += e.rotation;
}

function zoomFunc(e:TransformGestureEvent):void{
    test_mc.scaleX = test_mc.scaleY *= e.scaleX;
}

Multitouch.inputMode = MultitouchInputMode.GESTURE;

取得するタッチの種類を設定します。こうすると、OS標準のタッチイベントを処理できます。
もしもジェスチャーを独自に実装する場合は「TOUCH_POINT」を設定します。併用はできません。

指を使ってくるくる回す処理をする場合は「TransformGestureEvent.GESTURE_ROTATE」を使用します。
その際、「TransformGestureEvent.GESTURE_ROTATE」では、一回の処理ごとの角度を取得出来ます。
あくまで、「一回の処理ごと」なので、「ENTER_FRAME」と同様に、代入ではなく加算します。

次に、指を開いて拡大させる処理です。「TransformGestureEvent.GESTURE_ZOOM」を追加します。
「TransformGestureEvent.GESTURE_ZOOM」では、一回の処理ごとのスケールを取得します。
スケールはパーセンテージで取得するので、ここは掛け算します。

ルイズがとても可愛いですね。

てことで、簡単な解説を終わります。今回使用したPCは、HPのtx2という機種です。
他にもタッチに対応したPCは色々出てるので、試してみるといいでしょう。

動作サンプル（重いかもしれないんで別窓で）

サンプルファイル一式（Flash CS4形式）

最終的には上のようなものを作ります。
サンプルファイルは、きちんとクラス作ってますが、一応ココでの解説では、タイムラインコードで示します。
多分コピペすれば動くはず。

んで、このゆらゆら動くアニメーションには、BetweenAS3.bezierというメソッドを使います。
bezierといえば、こんな感じ。あとはここもいい感じの解説があります。

ただし、全てのパーティクルに対して個々にベジェ曲線を設定するわけにもいかんので、ベジェ曲線のコントロールポイントの数とか位置はランダムに取得するようにしたいのです。

//パーティクルのベジェの直径
var dist:int = 500;
//コントロールポイントの最大値、この変数に1を足した数が最大値になる。
var bezierMax:int = 10;
for (var i:int = 0 ; i < len ; i++) {
    //-----------
    //xzの基準位置を取得
    var centerX:int = particleArray[i].x;
    var centerZ:int = particleArray[i].z;
   
    //Tweenの最小値を計算
    var minX:int = centerX - dist / 2;
    var minZ:int = centerZ - dist / 2;
   
    //ベジェのコントロールポイントの数
    var countX:int = (Math.random() * bezierMax) + 2;
    var countZ:int = (Math.random() * bezierMax) + 2;
   
    //ベジェのコントロールポイントを格納する。
    var pointArrayX:Array = new Array();
    var pointArrayZ:Array = new Array();
    //ベジェを格納するオブジェクト
    var pointObj:Object = new Object();
   
    //ベジェのコントロールポイントを算出
    for (var forX:int = 0 ; forX < countX ; forX++) {
        pointArrayX.push( int(Math.random() * dist) + minX );
    }
    for (var forZ:int = 0 ; forZ < countZ ; forZ++) {
        pointArrayZ.push( int(Math.random() * dist) + minZ );
    }
   
    //Tweenの引数用のオブジェクト
    pointObj.x = pointArrayX;
    pointObj.z = pointArrayZ;

    var tweenXZ:IObjectTween = BetweenAS3.bezier(particleArray[i] , { x:centerX , z:centerZ } , null , pointObj , tweenTime , Linear.linear);
}

こんな感じで、bezierメソッドの第4引数にベジェのコントロールポイントを渡すのですが、ここの値はオブジェクト型を渡せばいいので、予めランダムな値の[x , y]というプロパティを持ったオブジェクトを作って、そいつを渡せば、ランダムなベジェ曲線のアニメーションを作ることができます。

その際に

//xzの基準位置を取得
var centerX:int = particleArray[i].x;
var centerZ:int = particleArray[i].z;
   
//Tweenの最小値を計算
var minX:int = centerX - dist / 2;
var minZ:int = centerZ - dist / 2;

こんな感じで、それぞれのプロパティの値を中心にして、コントロールポイントの範囲を決めてやります。

あとは、この処理を前回のエントリーのコードに移植してあげればOK。
てなわけで、タイムラインで動かす場合は下のコードををコピペしてみてくれ。

 import org.papervision3d.view.BasicView;
import org.papervision3d.materials.special.MovieAssetParticleMaterial;
import org.papervision3d.objects.special.ParticleField;
import org.papervision3d.cameras.CameraType;

import org.libspark.betweenas3.BetweenAS3;
import org.libspark.betweenas3.easing.Linear;
import org.libspark.betweenas3.events.TweenEvent;
import org.libspark.betweenas3.tweens.IObjectTween;
import org.libspark.betweenas3.tweens.ITween;


var world:BasicView = new BasicView(640 , 320 , true , false , CameraType.DEBUG);
var particleTweenArray:Array = new Array();

var mf:MovieAssetParticleMaterial = new MovieAssetParticleMaterial("test");
mf.smooth = true;

var fld:ParticleField = new ParticleField(mf , 200 , 1);

stage.addChild(world);
world.scene.addChild(fld);

world.startRendering();

fld.y = -500
world.camera.zoom = 50;

var tweenTime:int = 10;
var particleArray:Array = fld.particles;
var len:int = particleArray.length;

//--------------
//パーティクルのベジェの直径
var dist:int = 500;
//コントロールポイントの最大値、この変数に1を足した数が最大値になる。
var bezierMax:int = 10;
//--------------

var delay:Number = 0;
for (var i:int = 0 ; i < len ; i++) {
    particleArray[i].y = 0;
    
    //-----------
    //xzの基準位置を取得
    var centerX:int = particleArray[i].x;
    var centerZ:int = particleArray[i].z;
    
    //Tweenの最小値を計算
    var minX:int = centerX - dist / 2;
    var minZ:int = centerZ - dist / 2;
    
    //ベジェのコントロールポイントの数
    var countX:int = (Math.random() * bezierMax) + 2;
    var countZ:int = (Math.random() * bezierMax) + 2;
    
    //ベジェのコントロールポイントを格納する。
    var pointArrayX:Array = new Array();
    var pointArrayZ:Array = new Array();
    var pointObj:Object = new Object();
    
    //ベジェのコントロールポイントを算出
    for (var forX:int = 0 ; forX < countX ; forX++) {
        pointArrayX.push( int(Math.random() * dist) + minX );
    }
    for (var forZ:int = 0 ; forZ < countZ ; forZ++) {
        pointArrayZ.push( int(Math.random() * dist) + minZ );
    }
    
    //Tweenの引数用のオブジェクト
    pointObj.x = pointArrayX;
    pointObj.z = pointArrayZ;
    //-----------
    
    var tweenY:IObjectTween = BetweenAS3.tween(particleArray[i] , { y:2000} , null , tweenTime , Linear.linear);
    
    //-----------
    var tweenXZ:IObjectTween = BetweenAS3.bezier(particleArray[i] , { x:centerX , z:centerZ } , null , pointObj , tweenTime , Linear.linear);
    //-----------
    
    var tweenXYZ:ITween = BetweenAS3.parallel(tweenY , tweenXZ);
    tweenY.stopOnComplete = false;
 
    delay += 0.5;
   
    var delayTween:ITween = BetweenAS3.delay(tweenXYZ , delay);
    delayTween.play();
   
    particleTweenArray.push(tweenXYZ);
    delayTween.addEventListener(TweenEvent.COMPLETE , tweenCompFunc(i));
}
function tweenCompFunc(index:int):Function {
    return function(e:TweenEvent):void {
        particleTweenArray[index].play();
    }
}

最終的には↓のような物を作ります。

動作サンプル（重いかもしれないんで別窓で）

サンプルファイル一式（Flash CS4形式）

前回はParticleFieldで生成されるパーティクルにアニメーションを適用させる方法までを解説しました。

今回は、それに味付けして、個々にアニメーションするようにして

こんなやつを作ってみましょう。

因みに、用意したサンプルのソースでは、ParticleFieldクラスのサブクラスとして実装しています。

まず、パーティクルのアニメーションをずらすには、「delay()」を使います。
前回のコードを、

var delay:Number = 0;
for (var i:int = 0 ; i < len ; i++) {
    particleArray[i].y = 0;
    var tweenY:IObjectTween = BetweenAS3.tween(particleArray[i] , { y:2000} , null , tweenTime , Linear.linear);
   
    var delayTween:ITween = BetweenAS3.delay(tweenY);
    delayTween.play();
}

とか書けば、一個一個ばらばらにアニメーションを開始すると思います。
この際のyの目標座標は、ParticleFieldのデフォルトの高さである2000に設定します。

前回は、fld.fieldHeightこうかきましたが、どうやらprivateらしく、実行したら、値にアクセスできませんでした。

んで、このままだとアニメーションが終わったら、終わったまんまになってしまうので、リピート再生させるために「stopOnComplete = false;」を設定してあげなくてはいけませんが、delayTweenのほうでリピート再生させると、ディレイ時間も反映させてしまうため、ものによっては、ディレイ時間が20秒とかになってしまいます。

なので、

var particleTweenArray:Array = new Array();
var delay:Number = 0;
for (var i:int = 0 ; i < len ; i++) {
    particleArray[i].y = 0;
    var tweenY:IObjectTween = BetweenAS3.tween(particleArray[i] , { y:2000} , null , tweenTime , Linear.linear);
    tweenY.stopOnComplete = false;
   
    var delayTween:ITween = BetweenAS3.delay(tweenY);
    delayTween.play();

    particleTweenArray.push(tweenY);
    delayTween.addEventListener(TweenEvent.COMPLETE , tweenCompFunc(i));
}
function tweenCompFunc(index:int):Function {
    return function(e:TweenEvent):void {
        particleTweenArray[index].play();
    }
}

こんな風に書き換えます。

ディレイを与えたムービーが終わったら、リピート再生になっているtweenYのほうを再生開始するように設定します。

次回はゆらゆら動くようなアニメーションをつけてみます。

因みに、タイムラインコードとして書く場合の全てのコードは

import org.papervision3d.view.BasicView;
import org.papervision3d.materials.special.MovieAssetParticleMaterial;
import org.papervision3d.objects.special.ParticleField;
import org.papervision3d.cameras.CameraType;

import org.libspark.betweenas3.BetweenAS3;
import org.libspark.betweenas3.easing.Linear;
import org.libspark.betweenas3.events.TweenEvent;
import org.libspark.betweenas3.tweens.IObjectTween;
import org.libspark.betweenas3.tweens.ITween;


var world:BasicView = new BasicView(640 , 320 , true , false , CameraType.DEBUG);
var particleTweenArray:Array = new Array();

var mf:MovieAssetParticleMaterial = new MovieAssetParticleMaterial("test");
mf.smooth = true;

var fld:ParticleField = new ParticleField(mf , 200 , 1);

stage.addChild(world);
world.scene.addChild(fld);

world.startRendering();

fld.y = -500
world.camera.zoom = 50;

var tweenTime:int = 10;
var particleArray:Array = fld.particles;
var len:int = particleArray.length;

var delay:Number = 0;
for (var i:int = 0 ; i < len ; i++) {
    particleArray[i].y = 0;
    var tweenY:IObjectTween = BetweenAS3.tween(particleArray[i] , { y:2000} , null , tweenTime , Linear.linear);
    tweenY.stopOnComplete = false;
  
    delay += 0.5;
   
    var delayTween:ITween = BetweenAS3.delay(tweenY , delay);
    delayTween.play();
   
    particleTweenArray.push(tweenY);
    delayTween.addEventListener(TweenEvent.COMPLETE , tweenCompFunc(i));
}
function tweenCompFunc(index:int):Function {
    return function(e:TweenEvent):void {
        particleTweenArray[index].play();
    }
}

そしてできたものがこれです。（重いかもしれないんで別窓で）

サンプルファイル一式（Flash CS4形式）

それにしても、こうしてAdobe公式のリファレンスと体裁を同じくしてくれると楽でいいですね。
英語ほとんど分りませんが、こういう形式にしてもらえると、変数・戻り値・引数の型を見ればなんとなくわかりますからね。

ちなみに、Papervision3Dの使い方に関しては、こちらのブログが詳しいです。
今回Papervision3Dのバージョンは2.1 rev920を使います。
また、アニメーション時のTweenライブラリに、BetweenAS3を利用します。使用するバージョンはAlpha r3022です。
それぞれダウンロードしてクラスパスを通すか、Flaファイルと同一階層に[org]以下を入れて作業してください。

そんなこんなで本題に入ります。

ParticleFieldに関してはいろんなところで紹介されているので詳細は省きますが、指定した数分だけ、パーティクルをランダムに指定したエリアに配置してくれるという便利なクラスです。

使い方はこのサイトがわりとシンプルに解説してくれていますね。

要は、[ParticleFieldクラス]のインスタンスを、Papervision3DのsceneにaddChildしてあげればいいわけですね。

ちなみに、こんな風になります。

ParticleFieldは、第一引数に、パーティクルのマテリアルを受け取りますが、たいていのチュートリアルでは[ParticleMaterialクラス]のインスタンスを渡しています。
このクラスは、指定された色とサイズの正方形をパーティクルの素材にするようです。

ただ、できれば自分で作った素材を使いたいものです。
そうしてドキュメントをたぐっていったら、[ParticleMaterialクラス]のサブクラスに[BitmapParticleMaterial][MovieAssetParticleMaterial]というのがあるじゃないですか。

[BitmapParticleMaterialクラス]はパーティクルマテリアルのソースにBitmapDataを、[MovieAssetParticleMaterialクラス]は、リンケージさせたインスタンスをそれぞれ指定できるようです。
しかもインスタンスを指定する場合、アニメーションさせることも可能らしい。

てな訳で、ちょいと光ってるグラフィックを作って"test"という名前でリンケージさせて

var mf:MovieAssetParticleMaterial = new MovieAssetParticleMaterial("test");
var fld:ParticleField = new ParticleField(mf , 200 , 1);

 こうします。
すると指定したグラフィックで、200個のパーティクルを、指定した大きさでランダムに配置します。
ちなみに、サイズの部分に引数を渡さない場合、幅、高さ、奥行きはデフォルト値の2000になります。

さて、問題はここからです。

ここまでできれば、後はこれらのパーティクル一個一個をbeTweenAS3でTweenさせてやればいい。
beTweenAS3のパフォーマンスならば、200個程度きっと軽々さ！？

でもどうやってパーティクル一個一個を取得するんだろう？

そうしてまた、ドキュメントをたぐって[particles]というパラメータを発見、さすがにドキュメントだけでは分らなかったので、幾つかのサイトを見たら、どうやら画面に配置したパーティクルを格納した配列らしい。

[ParticleFieldクラスの]親クラスである[Particlesクラス]を見てみると[addParticle(particle:Particle):void]なんてのがあって、最終的には[particles]には[Particleクラス]のインスタンスの配列になるっぽい。

てことで、「particles[i].x」とか書けば、見事パーティクル一個一個の座標を操作できる。

var tweenTime:int = 10;
var particleArray:Array = fld.particles;
var len:int = particleArray.length;
for (var i:int = 0 ; i < len ; i++) {
    //パーティクルの位置を一番下に
    particleArray[i].y = 0;
    var tweenY:IObjectTween = BetweenAS3.tween(particleArray[i] , { y:fld.fieldHeight} , null , tweenTime , Linear.linear);
    tweenY.stopOnComplete = false;
    tweenY.play();
}

で、各パーティクルは、下から上までアニメーションします。
beTweenAS3に関してはコチラとかが分りやすいです。
あとは、にゃあプロジェクトさんが、色々とやってるようです。

ちなみに上記コードは、particleArray[i]のyに0を入れた後、beTweenAS3で0～fld.fieldHeight「フィールドの高さ、つまり一番上」まで、等速で10秒のアニメーションをさせます。

tweenY.stopOnComplete = false;

[stopOnComplete]はその名の通り、アニメーションが終了したらstopするか？
の設定なので、trueで一回きり、falseでリピートになります。これで、個々のパーティクルを下から上にリピート再生させることができました。

ただし、このままだと全てのパーティクルが、一斉に動き出した上に動きも全く一緒です。
なので、アニメーションの開始をずらして、さらには、もっとランダムっぽい曲線的な動きとかを入れたいし、あとは開始点と終了点で違和感なく消えてもらいたいですね。

もういい加減眠いので、アニメーションのブラッシュアップ部分は次回に回します。

ちなみに、今回の全コード

import org.papervision3d.view.BasicView;
import org.papervision3d.materials.special.MovieAssetParticleMaterial;
import org.papervision3d.objects.special.ParticleField;
import org.papervision3d.cameras.CameraType;

import org.libspark.betweenas3.BetweenAS3;
import org.libspark.betweenas3.easing.Linear;
import org.libspark.betweenas3.events.TweenEvent;
import org.libspark.betweenas3.tweens.IObjectTween;
import org.libspark.betweenas3.tweens.ITween;


var world:BasicView = new BasicView(640 , 320 , true , false , CameraType.DEBUG);
var particleTweenArray:Array = new Array();

var mf:MovieAssetParticleMaterial = new MovieAssetParticleMaterial("test");
mf.smooth = true;

var fld:ParticleField = new ParticleField(mf , 200 , 1);

stage.addChild(world);
world.scene.addChild(fld);

world.startRendering();

fld.y = -500
world.camera.zoom = 50;

var tweenTime:int = 10;
var particleArray:Array = fld.particles;
var len:int = particleArray.length;
for (var i:int = 0 ; i < len ; i++) {
    //パーティクルの位置を一番下に
    particleArray[i].y = 0;
    var tweenY:IObjectTween = BetweenAS3.tween(particleArray[i] , { y:2000} , null , tweenTime , Linear.linear);
    tweenY.stopOnComplete = false;
    tweenY.play();
}

>>ダウンロードはコチラ

マイコミさんでやらせてもらってるセミナーで受講生からの希望があったんで、Flvプレイヤーを公開します。
一応ちょこっとだけ改造して、flv f4v mp4(H264のみ)に対応しています。

一応ソースコード（CS3形式）も添付してるんで、ご参考までに見てみてください。

一応コチラにもソースをぺとり

import fl.video.*;
import flash.events.*;
import flash.display.Sprite;
import flash.filesystem.File;
import flash.net.FileFilter;
import flash.desktop.*;

stage.quality = "best";
flle_txt.visible = false;

//ステージの拡大モードを設定
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;

//widhtを基準とした、heightのアス比
var aspect:Number;

//コントロールを設定
player.playPauseButton = control_mc.playPauseButton_mc;
player.stopButton = control_mc.stopButton_mc;
player.seekBar = control_mc.seekBar_mc;
player.muteButton = control_mc.muteButton_mc;
player.volumeBar = control_mc.volumeBar_mc;
player.fullScreenButton = control_mc.fullScreenButton_mc;
//下マージン
var bottomMargin:int = 3;
//プレイヤーとコントロールのマージン
var ctrlMargin:int = 4;

//プレイヤーの初期設定
player.autoRewind = true;
player.x = 5;
player.y = 30;

//player.source = "test.flv";

//メタを取得できたら、コントロールをビデオの下に吸着
player.addEventListener(MetadataEvent.METADATA_RECEIVED , moveControl);
//吸着用のメソッド
function moveControl(event:MetadataEvent):void{
    aspect = player.metadata.height/player.metadata.width;
    windowFit();
}

//ステージのサイズに合わせてアス比固定で拡大縮小
stage.addEventListener(Event.RESIZE , videoResize);
function videoResize(event:Event):void{
    var playerWidth:Number = stage.stageWidth - 10;
    var playerHeight:Number = playerWidth * aspect;
    var ctrlsHeight:Number = control_mc.height + bottomMargin + player.y;
   
    if(playerHeight + ctrlsHeight < stage.stageHeight){
        player.setSize(playerWidth , playerHeight);
        //ドラッグターゲットのサイズ設定
        dragTarget_mc.width = playerWidth;
        dragTarget_mc.height = playerHeight;
        //BGのサイズ指定
        bg_mc.width = stage.width;
        bg_mc.height = stage.height;
    }else{
        playerHeight = stage.stageHeight - ctrlsHeight;
        playerWidth = playerHeight/aspect;
        player.setSize(playerWidth , playerHeight);
        //ドラッグターゲットのサイズ設定
        dragTarget_mc.width = playerWidth;
        dragTarget_mc.height = playerHeight;
        //BGのサイズ指定
        bg_mc.width = stage.width;
        bg_mc.height = stage.height;
    }
    ctrlMove();
}

//ウィンドウを操作するためのオブジェクト
var window:NativeWindow = this.stage.nativeWindow;

//ウインドウを初期サイズにフィットさせる
function windowFit(){
    window.height = 34 + player.y + player.metadata.height + ctrlMargin + control_mc.height + bottomMargin;
    window.width = 18 + player.metadata.width;
   
    flle_txt.text = window.height + "　" + window.width;
   
    player.setSize(player.metadata.width , player.metadata.height);
   
    ctrlMove();
}

//コントロールを右下に吸着
function ctrlMove():void{
    control_mc.y = player.y + player.height + 5;
    close_btn.x = (player.width+5) - close_btn.width - 4;
   
    var mov:Number = control_mc.x = (player.width+5) - 318;
   
    if(mov >= 7){
        control_mc.x = mov;
    } else {
        control_mc.x = 7;
    }
}

//ボタン設定
open_btn.buttonMode = true;
fit_btn.buttonMode = true;
close_btn.buttonMode = true;
//フィットボタンでムービーサイズを元に戻す
fit_btn.addEventListener(MouseEvent.CLICK , fitVideo);
//ムービーリサイズ
function fitVideo(event:MouseEvent){
    windowFit();
}
//クローズボタン
close_btn.addEventListener(MouseEvent.CLICK , winClose);
function winClose(event:MouseEvent){
    window.close();
}

//オープンボタンでのファイル選択処理
open_btn.addEventListener(MouseEvent.CLICK , fileOpen);

//ファイルタイプをFLVのみに設定
//ファイルブラウズ処理
var fileLoader:File = new File();
fileLoader.addEventListener(Event.SELECT , fileSelected);
var filter:FileFilter = new FileFilter("Flvファイル", "*.flv; *f4v; *mp4");

function fileOpen(event:MouseEvent):void{
    fileLoader.browseForOpen("ファイルの選択", [filter]);
}
function fileSelected(event:Event){
    player.source = fileLoader.url;
    flle_txt.text = fileLoader.url;
}

//ドラッグ＆ドロップ処理
dragTarget_mc.addEventListener(NativeDragEvent.NATIVE_DRAG_ENTER, onDragIn);
dragTarget_mc.addEventListener(NativeDragEvent.NATIVE_DRAG_DROP, onDrop);

//ドラッグ許可
function onDragIn(event:NativeDragEvent):void{
    flle_txt.text = "Drag";
    var dropData:Clipboard = event.clipboard;

    if (dropData.hasFormat(ClipboardFormats.FILE_LIST_FORMAT)) {
        NativeDragManager.acceptDragDrop(event.target);
    }
}

//ドロップ処理
function onDrop(event:NativeDragEvent):void{
   
    var droppedData:Array = event.clipboard.getData(ClipboardFormats.FILE_LIST_FORMAT);
   
    var file:File = droppedData[droppedData.length -1];
    if(file.extension == "flv" || file.extension == "FLV" || file.extension == "F4V" || file.extension == "f4v" || file.extension == "mp4" || file.extension == "MP4"){
        player.source = file.url;
    }
}

>>Flaファイルをダウンロード

とうとうこのエントリーを最後に、このサンプルともお別れですね。
そういえば、このサンプルの元ネタとも、今週でお別れですね。寂しいものです。

さて、前回はエレメントの生成・追加をやったのですが、その際にエレメントがダブってしまうのは、あんまりよろしくないぞ。
というわけで、「XMLクラスに、例えば指定エレメントのノードがあるかどうか調べるメソッドでもないかしら？」と思って探してみたのですが、残念ながらそんな便利なメソッドはありませんでした。

例えば
XMLデータ.何かしらのメソッド(@id == "なんか文字列");
で、Boolean型を返してくれると非常にありがたかったのですが・・・

しかし、無いもんは無い。って事で、他の処理で代用するしかありません。
要するに、指定した値での、XMLエレメントの有無チェックが出来ればいいのです。

というわけで実験。

if(test_xml.member.(name =="田井中　律") ){
    trace("エレメントがありますよ～ﾉｼ");
}

 「エレメントがありますよ～ﾉｼ」と出力されます。
しかし・・・

if(test_xml.member.(name =="ありえないエレメント") ){
    trace("エレメントがありますよ～ﾉｼ");
}

「エレメントがありますよ～ﾉｼ」と出力されます。
最悪だ・・・。

そこに、救世主が現れた。
その名も「toXMLString()メソッド」

そもそもこのメソッドは、実行したXML オブジェクトのエレメントのストリング表現を返すメソッドです。
なので、例えば「test_xml.member.(name =="田井中　律").toXMLString()」を実行すると

<member part="Dram">
  <name>田井中　律</name>
</member>

上記の値を、XMLデータではなく、String値で返します。
大切なことなので2回言いますが、上記データは、XMLデータではなくStringデータです。

そして、上記のスクリプトを

if(test_xml.member.(name =="田井中　律").toXMLString() ){
    trace("エレメントがありますよ～ﾉｼ");
}

if(test_xml.member.(name =="ありえないエレメント").toXMLString() ){
    trace("エレメントがありますよ～ﾉｼ");
}

このように記述すれば、上のコードは、「エレメントがありますよ～ﾉｼ」と出力され、下のコードは何も出力されません。else節があれば、そちらが実行されます。

てなわけで

前回のエントリーの、あずにゃん追加ボタン部分の関数を

/*----------------------------------------------
■addAzusaHandler
■概要
test_xmlにazunyan_xmlを追加する。
----------------------------------------------*/
function addAzusaHandler(event:MouseEvent):void{
    var azunyanName:String = azunyan_xml.name.toString();
   
    //test_xmlにあずにゃんがいたらreturnする。
    if(test_xml.member.(name == azunyanName).toXMLString() ){
        return;
    }
   
    test_xml.appendChild(azunyan_xml);
    inIt();
}

このように書き換えました。

var azunyanName:String = azunyan_xml.name.toString();

で、追加予定のXMLデータのnameエレメントの値を取得して、

if(test_xml.member.(name == azunyanName).toXMLString() ){
    return;
}

 上記処理で、当該memberエレメントが既に存在していたら、returnで、関数から抜けます。

つぎに俺も入部ボタン部分の関数を

/*----------------------------------------------
■addOreHandler
■概要
oreNameの値とorePartの値から、XMLノードを生成して
test_xmlに追加する。
----------------------------------------------*/
function addOreHandler(event:MouseEvent):void{
    var nameStr:String = oreName.text;
    var partStr:String = orePart.text;
   
    //テキストが空の場合return
    if(nameStr == "" || partStr == ""){
        return;
    }
   
    //名前・パートが被る場合return
    if(test_xml.member.(@part == partStr).(name == nameStr).toXMLString() ){
        return;
    }
   
    //入力内容から、XMLを生成する
    var addXML:XML = <member part={partStr}><name>{nameStr}</name></member>;
    test_xml.appendChild(addXML);
    inIt();
}

 こんな風に書き換えます。
こちらは、名前・パートの両方で抽出しています。一人の人間が複数パートを担当したり、ひとつのパートに複数担当がいたりってのはよくあるんで、Jazzとかオーケストラだと特に。

>>Flaファイルをダウンロード

しつこく、このサンプルを使います。

さて、次にプログラムからXMLエレメントを生成したり、XMLオブジェクトにエレメントを追加する方法を解説します。
これが出来ると、他のアプリケーションとのデータのやり取りの際に、統一された汎用フォーマットを利用できるので、開発が楽になります。

上記サンプルだと、「あずにゃん入部」ボタンと「俺も入部」ボタンになりますね。

あずにゃん入部ボタンは予め用意した下記のようなXMLデータを利用しています。

//あずにゃんのデータ
var azunyan_xml:XML =
<member part="Guitar">
    <name>中野　梓</name>
</member>;

 追加するボタンの処理は

test_xml.appendChild(azunyan_xml);

 このように、「XMLデータ.appendChild(追加するXMLデータ)」と記述します。
すると、「<houkagoTeaTime>」エレメントの末尾に、指定したXMLデータが追加されます。

その後、コンボボックスのデータプロバイダの設定処理を行えば、入部した部員やパートがコンボボックスに追加されます。

次に「俺も入部」ボタンで、入力データから生成したエレメントの挿入は

var nameStr:String = oreName.text;
var partStr:String = orePart.text;

//テキストが空の場合return
if(nameStr == "" || partStr == ""){
    return;
}

var addXML:XML = <member part={partStr}><name>{nameStr}</name></member>;
test_xml.appendChild(addXML);

 このように記述します。「oreName」「orePart」はそれぞれテキスト入力のテキストフィールドです。どちらかのテキストが入ってなかったら、returnによって、以降の処理を飛ばします。

キモになるのは、

var addXML:XML = <member part={partStr}><name>{nameStr}</name></member>;

この部分です。
ここで実際に入力データを格納した変数から、XMLエレメントを生成してるのですが、その際XML表現の中に変数を使う場合は「{変数名}」とします。

もし、{}を使用しなかった場合、「partStr」や「nameStr」は普通に文字列として扱われて、下記のようなXMLエレメントになってしまいます。気をつけましょう。

<member part=partStr>
    <name>nameStr</name>
</member>;

 これで、XMLデータの動的な生成が出来ましたが、問題が残ってます。
このままだと、あずにゃんが何人も何人も、桜高校軽音部に入部できてしまいます。

それはいけません。

なぜなら僕らの生きがいに、あずにゃんは一人だけです。だからこそ可愛いのです。

それ以外にも、例えばコンボボックスにデータを再設定する際に、「その1」のやり方のまんまだと、あずにゃんを追加した場合に、Guitarの選択肢が2つ入ってしまったりといった残念が発生します。

てなわけで、次回はエレメントの有無をチェックしたり、ユニークチェックしたりとかそういう処理を紹介します。

>>Flaファイルをダウンロード

今回も、このサンプルを使います。

前回のエントリーでコンボボックスに、それぞれ「nameエレメント」と、「part属性」をデータプロバイダとして設定しました。

コンボボックスの、どの値（セル）が選択されているかは「コンボボックスインスタンス.selectedItem」で参照できるので、

nameCmb.addEventListener(Event.CHANGE , nameSelectHandler);
/*----------------------------------------------
■nameSelectHandler
■概要
nameCmbから、エレメントを選択すると、選択されたエレメントをselectedTxtAreaに表示し
当該エレメントをsetected_xmlに代入する
----------------------------------------------*/
function nameSelectHandler(event:Event):void{
    var selectedNodeName:String = event.target.selectedItem.data.toString();
    setected_xml = new XMLList(test_xml.member.(name == selectedNodeName) );
    selectedTxtArea.text = setected_xml;
}

 コンボボックスの、選ばれているセルが変更された際に発行されるイベント「CHANGEイベント」で、新しく選ばれたセルが保持している「data」プロパティを取得した値により、「test_xml」から抽出しています。

「part属性」で抽出する場合は

setected_xml = new XMLList(test_xml.member.(@part == selectedNodepart) );

こうなります。

「ActionScript3.0でXML　XMLの基本的な使い方」の応用ですね。

因みに、ひとつのパートに2人（ツインギター）や、一人の人間が複数パート（ギター&ボーカル）なんてケースも存在するため、抽出したデータは、XMLListクラスを利用します。
仮に、XMLクラスを使用した場合、抽出されたエレメントが単一ならば問題ないのですが、複数のエレメントが抽出された場合、ランタイムエラーが発生します。

>>Flaファイルをダウンロード

ActionScript 3.0でXMLを扱う仕組みが簡単になって凄く楽になりましたねぇ。

上のサンプルでは、一番右のテキストエリアに生XMLデータ、左のテキストエリアに、左側のコンボボックスから抽出されたエレメントのみを表示するようになっています。

さらに、新しいエレメントの追加や、ユーザーの入力から新たなノードを作る機能と、追加される際に、すでに登録されいるかどうかを調べて、2重登録を防ぐ機能を実装しています。

とはいえ、いきなり全機能を解説するのはアレなんで、何回かに分けて、ActionScript3.0でXMLを扱う仕組みをちょこっと解説してみようと思います。

まずはXMLを用意しましょう。

//テスト用XMLデータ
var test_xml:XML =
<houkagoTeaTime>
    <member part="Guitar">
        <name>平沢　唯</name>
    </member>
    <member part="Bass">
        <name>秋山　澪</name>
    </member>
    <member part="Keyboard">
        <name>琴吹　紬</name>
    </member>
    <member part="Dram">
        <name>田井中　律</name>
    </member>
</houkagoTeaTime>;

こんな感じでScriptを書きます。AS3.0では、コード内にもXMLを記述出来るんで、一々読み込む必要のないデータや、構造体を作って管理していた変数なんかは、今後XMLに統一するのもいいかもしれませんね。

さて、早速これをプログラム内で使ってみましょう。
てことで、左側のコンボボックスにXMLのデータから、値を抽出して、初期設定してみましょう。

import fl.data.DataProvider;
//コンボボックスのデータプロバイダ。
var nameItems:Array;

function setNameCmb(){
    nameItems = new Array();
   
    for each(var elements:Object in test_xml.member){
        nameItems.push({
                       label:elements.name.toString() ,
                       data:elements.name.toString()
                       });
    }
    nameCmb.dataProvider = new DataProvider(nameItems);
}

サンプルの、「名前で抽出のコンボボックス」の設定の記述です。
nameCmbは、コンボボックスのインスタンス名ですので、コードの最後の

nameCmb.dataProvider = new DataProvider(nameItems);

この記述で、コンボボックスに「XMLから抽出した値を構造体に格納した配列」を設定しています。

んで、実際にXMLに対して処理をしてるのが

for each(var elements:Object in test_xml.member)

になります。

for eachは、()内の「in」の後ろに記述された、XMLエレメントに対して、エレメント数分、繰り返し処理を行います。
このプログラムだと「test_xmlの、memberというエレメントの数分、繰り返し処理をしなさい」という意味で、さらに「in」の前 の「var elements:Object」は、処理の対象のエレメントの一時確保変数です。まぁ「for文」の「var i:int = 0」みたいなもんだと思って下さい。

なので、正しくは「test_xmlの、memberというエレメントの数分、elementsという変数名で、繰り返し処理をしなさい」となります。

コンボボックスのデータプロバイダは、「label」と「data」が入った構造体の配列を使用するので

nameItems.push({
           label:elements.name.toString() ,
           data:elements.name.toString()
           });

このようになります。
これで、たとえば「nameItems[0].label」とか「nameItems[2].data」とかで、値をとりだすことができるようになります。要するに、「label」と「data」という2つのデータを対にして、リスト的に扱えるようになるわけです。

なるほど、コンボボックスとは相性が良さそうです。

ActionScript3.0では、「タグ名.タグ名」という風に、「childNode」とか書かずに、直接タグ名でエレメントを操作できるので、

label:elements.name.toString()

これだけで、対象ノードのデータを取得することができます。
上の例だと、elementsは、for each の処理対象のtest_xml.memberエレメントなので、

test_xml.member[i].name.toString();

て な具合になりますね。ちなみに、複数のノードがある場合は、上のように「test_xml.member[5]」とかで、直接エレメントにアクセスすることが できるので、for each を使わなくても、通常のfor文使って、[i]でXMLエレメントを操作しても構いません。for eachを使った方が圧倒的に楽ですが・・・

何はともあれ、これで晴れてバンドメンバーの名前を抽出出来ました。

では次は担当パートを抽出してみたいところですが、こちらは「<member part="Bass">」のように、属性になっています。さてどうやってとりだそう・・・

AS2.0時代は、attributeなんてもんを使ってましたが、AS3.0からは

test_xml.member[i].@part.toString();

でOK。名前の前に「@」をつけるだけ。

なので、コンボボックスの「パートで抽出」は

partItems.push({
           label:elements.@part.toString() ,
           data:elements.@part.toString()
           });

これでOK。
ただし、ひとつのバンドに同じ楽器担当が複数いる場合もあるので（ツインギターとかツインボーカルとか）ユニークチェックをかけたりしてるんですが、それはまた次の機会に。

>>Flaファイルをダウンロード

「ActionScript3.0のXMLの取り扱い その1.」の方を先に書いたあとで、そういえば、この話のさらに前提となる部分を多く省いてたなぁという事で、その辺を解説します。

//テスト用XMLデータ
var test_xml:XML =
<houkagoTeaTime>
    <member part="Guitar">
        <name>平沢　唯</name>
    </member>
    <member part="Bass">
        <name>秋山　澪</name>
    </member>
    <member part="Keyboard">
        <name>琴吹　紬</name>
    </member>
    <member part="Dram">
        <name>田井中　律</name>
    </member>
</houkagoTeaTime>;

こんなXMLデータを用意したとします。

そもそもAS3.0でXMLデータを扱う場合は

1. XMLクラス
2. XMLListクラス

を使います。

これらの違いは、詳しくはこちらのリンクにまかせるとして、簡単に説明すると。
XMLのタグで表わされる部分を、ノードだとかエレメントだとか呼んだりしますが、XMLクラスは、必ず一つのXMLエレメントで構成されている必要があります。

なので、複数のエレメントを同じレベルに並べることができません。

上記サンプルの例では、test_xmlは「<houkagoTeaTime>」という単一のエレメントで構成されています。

XMLListクラスは、複数のエレメントを扱います。
例えば

var testData:String =
<member part="Guitar">
    <name>平沢　唯</name>
</member>;

testData += <member part="Bass">
    <name>秋山　澪</name>
</member>;

testData += <member part="Keyboard">
    <name>琴吹　紬</name>
</member>;

testData += <member part="Dram">
    <name>田井中　律</name>
</member>;

こんなコードがあったとして、
testDataの値は

<member part="Guitar">
  <name>平沢　唯</name>
</member>
<member part="Bass">
  <name>秋山　澪</name>
</member>
<member part="Keyboard">
  <name>琴吹　紬</name>
</member>
<member part="Dram">
  <name>田井中　律</name>
</member>

このように、複数の「<member>」というエレメントで構成されたXML表現になります。
このString型の変数をXMLデータとして扱う場合。

var test_xml:XML = new XML(testData);

だと、コンパイルエラーになりますが

var test_xml:XMLList = new XMLList(testData);

という風に、XMLListクラスを利用すると、コンパイルエラーにはなりません。
ただし、複数のエレメントを持ったXMLListオブジェクトは、XMLクラスのメソッドを使う事が出来ないので、使いどころとしては、プログラム上で生成したXMLエレメントの一時作業用に、XMLListクラスを利用し、生成されたXMLListを、XMLクラスのオブジェクトと連結する。といったイメージでしょうか。

なので、基本的にはXMLクラスのオブジェクトに対して処理をします。

あとはエレメントの抽出方法ですが、
サンプルのXMLデータから値を抽出する場合の例をいくつか。

trace(test_xml.member);

の出力結果、すべての<member>エレメントを取得します。
<member part="Guitar">
  <name>平沢　唯</name>
</member>
<member part="Bass">
  <name>秋山　澪</name>
</member>
<member part="Keyboard">
  <name>琴吹　紬</name>
</member>
<member part="Dram">
  <name>田井中　律</name>
</member>

trace(test_xml.member.name);

の出力結果、すべての<member>の<name>エレメントを取得します。
<name>平沢　唯</name>
<name>秋山　澪</name>
<name>琴吹　紬</name>
<name>田井中　律</name>

trace(test_xml.member[0]);

の出力結果、指定したindexのエレメントを取得します。
<member part="Guitar">
  <name>平沢　唯</name>
</member>

trace(test_xml.member[0].name);

の出力結果、指定したindexのエレメントを取得します。
平沢　唯

trace(test_xml.member.@part);

属性を取得する場合、@を付けます。出力結果は
GuitarBassKeyboardDram

trace(test_xml.member[0].@part);

もちろんindexを指定することもできます。

trace(test_xml.member.(@part == "Dram") );

条件抽出する場合は上記のように記述。
出力結果は
<member part="Dram">
  <name>田井中　律</name>
</member>

trace(test_xml.member.(name == "秋山　澪") );

エレメントの値に対しても条件抽出できます。
出力結果は
<member part="Bass">
  <name>秋山　澪</name>
</member>

以上が、ActionScript3.0でXMLを扱う際の、ほんとのほんとに基礎部分です。
以下、用語紹介です。（Flashのヘルプから引用）

• エレメント : XML ドキュメント内の単一アイテム。開始タグと終了タグ (タグも含みます) の間にあるコンテンツにより識別されます。 XML エレメントには、テキストデータ、その他のエレメントを含めることができます。また、空であってもかまいません。

• 空のエレメント : 子エレメントを含まない XML エレメント。 空のエレメントは、自己終了タグ（<element/> など）として記述されることがよくあります。

• ドキュメント : 単一の XML 構造。 XML ドキュメントには、任意の数のエレメントを含めることができます (また、単一の空のエレメントのみで構成することもできます)。ただし、XML ドキュメントには、ドキュメント内の他のすべてのエレメントを含む単一の最上位エレメントが存在する必要があります。

• ノード : XML エレメントの別名。

• 属性：エレメント内部にネストする個別の子エレメントとしてではなく、attributename="value" の形式でエレメントの開始タグに記述されるエレメントに関連する名前付き値。

その方法は

1. FlvPlaybackコンポーネントから、フルスクリーンボタンが配置されたコンポーネントを選択する。
2. FLV Playback カスタム UI コンポーネントのFullScreenButtonを配置する。
3. enterFullScreenDisplayState () メソッドを実行する
4. スクリプトで実装する。

の4パターンが考えられるでしょう。

しかし、この4パターンのうち、1～3は、Flvムービーにしか適用できず。
さらに、FlvPlaybackコンポーネントを利用し、かつ、ディスプレイカードによるハードウェアアクセラレーションを利用する場合、コンポーネントの矩形範囲で拡大されてしまい、ビデオソースの解像度は無視されます。

例えば

1. 実際のビデオのソースは、1920×1080のフルHDサイズだが、初期起動時は480×270で表示する。
2. 画面に配置されたひとつのFlvPlaybackコンポーネントで、480×270画面内表示と、1920×1080フルスクリーンを切り替える。

上記のケースだと、フルHDの映像を480×270に縮小表示している場合、フルスクリーンにした際に
480×270で表示している画面をスケーリングしてしまうため（小さい動画をハードウェア側でスムージングを掛けて表示される）ソースがフルHDの映像だとしても、表示上480×270などに縮小している場合は、縮小された画面を引き伸ばしてしまい、小さい動画をただ引き伸ばしただけになってしまいます。

どうやらコレは、上記1～3のフルスクリーン実装方法だと、FlvPlaybackコンポーネントのメソッドを呼び出すかたちになるみたいなのですが（FlvPlaybackのenterFullScreenDisplayState () メソッド）どうやらこのメソッドを実行すると、FlvPlaybackコンポーネントの矩形範囲をハードウェアアクセラレーションでスケーリング表示するようです。（予想ですが！！）

結果、小さいサイズの動画をただ引き伸ばしたような映像になってしまいます。

そこで、FlvPlaybackコンポーネントの機能を使わずに、4の「スクリプトで実装する」ことにしましょう。
スクリプトで実装すると、Flvコンテンツだけでなく、実際のFlashコンテンツもFullScreenで表示することが出来るので、こちらで実装するほうが汎用性がありそうですしね。

さて、その方法ですが

stage.displayState = StageDisplayState.FULL_SCREEN;

と、stageのdisplayStateプロパティを、フルスクリーンなパラメータに設定するだけで、とりあえずFullScreenに出来ます。簡単です。プロパティにパラメータが入ったと同時にフルスクリーンが実行されます。
しかし問題が、コレだけではハードウェアアクセラレーションがかかりません。

なので、上記のコードを実行する前に、

stage.fullScreenSourceRect = new Rectangle(0, 0, 1920, 1080);

上記のコードを実行し、フルスクリーンで拡大する矩形エリアを設定します。

fullScreenSourceRectプロパティを設定すると
可能な場合、拡大 / 縮小は、ユーザーのコンピュータ上でグラフィックカードやビデオカードを使用してハードウェアで行われます。

てことで、こういうコードになります。

stage.fullScreenSourceRect = new Rectangle(0, 0, 1920, 1080);
stage.displayState = StageDisplayState.FULL_SCREEN;

FlvPlaybackコンポーネントのfullScreenTakeOverプロパティがtrueの場合（通常デフォルトでture）フルスクリーンに移行すると、自動的にFlvPlaybackコンポーネントは前面に表示され、フルHDのビデオのエリア「Rectangle(0, 0, 1920, 1080);」に対して、フルスクリーンのディスプレイアクセラレーションが実行されます。

この方法を利用すれば、Flvではなく、通常のFlashコンテンツに対してフルスクリーン機能を実装できますし、fullScreenTakeOverプロパティにfalseを設定した場合は、FlvPlaybackを含んだFlashコンテンツのデザインを、そのままフルスクリーンに出来ます。
その際は、Rectangleに対してRectangle(0, 0, Flashコンテンツの横幅, Flashコンテンツの高さ)を渡してやればOK！

ただし、フルスクリーンを実装する再は、スクリプトで実装する再もFlvPlaybackのメソッドを利用する場合も
必ずマウスクリックまたはキー操作をトリガにする必要がありあますので、ご注意を。

そして、貼り付けるHTML側の、allowFullScreenをtrueに設定してあげるのを忘れないように。

まずはコイツを見てくれ。
僕は、ココのアカウントを持っていないし、同様の問題に直面したときは、投稿日時からだいぶ日数が経ってたので、特にココにはコメントしなかったんだけれど、今後同様の問題に直面した人の救いになればと思ってエントリーを書いてみることにするよ。

前回、

movie.closeVideoPlayer(1);

にて、NetStreamを閉じましが、再度再生するために

movie.activeVideoPlayerIndex = 1;
movie.visibleVideoPlayerIndex = 1;
movie.source = "flvファイルへのパス";
movie.play();

このように記述すると、コンポーネントの表示上はミュートになっていないのに、音声が再生されません。
さらに、ボリュームのハンドルや、ミュートボタンを弄ると、音が流れ出します。

どうやら、ビデオとサウンドは、別々のプロセス（インスタンス）で管理されているみたいで、FLVPlaybackコンポーネントを生成したときは、ビデオとサウンドが両方生成され、closeVideoPlayer()メソッドを実行すると、ビデオとサウンドが両方削除されるが、その後に同じコンポーネントに対して
movie.source = "flvファイルへのパス";
movie.play();
上記を実行すると、ビデオ再生だけが生成され、サウンドは生成されず、音声ボタン等を操作したときに初めて生成されているようだ。（全部予想な！！）

この予想が正しければ、FlvPlaybackコンポーネントにサウンドを制御するプロパティがあって、それはきっとクラス型だ！
とあたりをつけて、ドキュメントを漁る。
ほどなくして、soundTransformというプロパティを発見。予想通りSoundTransformというクラスのインスタンスだ。
ということは、再度、FlvPlaybackで再生するときに、soundTransformプロパティを再設定してやればいけるはず！！ってことで

var sound:SoundTransform = new SoundTransform(1 , 0);
movie.soundTransform = sound;

コンストラクタに、SoundTransform(1 , 0);
で、第1引数にボリューム（1で最大音量）、第2引数にパン（0でパン無し）を与えて、生成したSoundTransformクラスのインスタンスを、FlvPlaybackコンポーネントのプロパティsoundTransformに渡します。

これで、晴れて音声が再生されるようになります。やったね♪

大きなFLVファイルをサーバに置いたら、ものすごい負荷で参ったｗｗｗ
てな事があって、
ならば、FLVPlaybackコンポーネントが表示される画面を閉じても裏でプログレッシブダウンロードが走ってるから、画面を閉じるたびに、きちんとNetStreamを閉じて、なるべく負荷がかからないようにしよう。

と考えたからなわけです。
そこで利用するのが「closeVideoPlayer()」メソッドです。

closeVideoPlayer()メソッドは、引数として渡されたindexのNetStream を閉じ、ビデオプレーヤーを削除します。

ここでいうビデオプレーヤーとは、FLVPlaybackコンポーネント自身ではなく、なんというか、FLVPlaybackコンポーネントに指定されている、プロセスみたいなもの？
僕はなんとなくこんな感じで理解してます。

さて、
■閉じたビデオプレーヤーがアクティブまたは可視のビデオプレーヤーである場合は、アクティブまたは可視のビデオプレーヤーを FLVPlayback インスタンスでデフォルトプレーヤーに設定します (インデックス 0)。
■デフォルトプレーヤーを閉じることはできません。閉じようとすると、エラーがスローされます。

とあるので、簡単な話、indexの値が0だと、closeVideoPlayer()メソッドを使えません。
なので、activeVideoPlayerIndexパラメータとvisibleVideoPlayerIndexを適当な数値にします。

仮に、movieという名前のFLVPlaybackコンポーネントが配置されているとして
例えばビデオ再生用の小窓をFlashのStageに表示させる場合に

movie.activeVideoPlayerIndex = 1;
movie.visibleVideoPlayerIndex = 1;
movie.source = "flvファイルへのパス";
movie.play();

と、予め再生する処理で上記の様に記述することで、この小窓を閉じる（非表示にしたり、removeChild()する）再に

movie.closeVideoPlayer(1);

上記の様に記述して、ネットコネクションを切ることが出来ます。
例えば、こんなソフトでネットワークを監視してみると、明らかに負荷が軽減されているのが分かります。

まぁ結局あまりたいした効果が出ずに、rtmpが使えるストリーミングサーバを借りたんですがねｗｗ

airを使うと、当然ユーザーのディスク領域にアクセスすることが出来るんで、通常のアプリのように、ファイルを読み込んで編集して上書きして～・・・ってなことができたりします。

まぁその辺はおいおいという事で、今回は「アプリケーションがインストールされているディレクトリから、アプリケーション用のデータディレクトリにファイルをコピーして、そのファイルを読み込む」っていう処理を書いてみましょう。

>>Flaファイルをダウンロード

そもそもこのコードを書いたきっかけが、スキン対応のデスクトップツールを作ろうってことで、ユーザーが自由にスキンをインストールできるようにしなきゃならんが、インストール直後のデフォルトスキンが必要だよね。ってことで、最初は、アプリケーションがインストールされてる、カレントディレクトリに、「skins」とかのフォルダを作って、XMLのファイルリストに個々のスキンフォルダを対応させようって考えてたんだけれども・・・

applicationDirectory配下のファイルにアクセスする方法

上記の記事で、AIRアプリケーションのアンインストール時には、自分で作成したファイルは削除されないのでそのまま残ってしまうという欠点がある。
さらに悪いことに、もう一度同じAIRアプリケーションをインストールしようとした場合、インストール先のディレクトリが残ったままだとインストールに失敗してしまうので要注意。

うおぉ、こりゃいかん・・・

ってことで、もちょっと調べたら、「applicationStorageDirectory」なるものを発見。
どうやら、ここは、アンインストール時に削除されるようで、ならば、スキンリストはここに作成しようと決断

ならば、最初のデフォルトスキンも含んだ、スキンフォルダをapplicationStorageDirectoryに作成しなきゃねって事で、「アプリケーションがインストールされているディレクトリから、アプリケーション用のデータディレクトリにファイルをコピーして、そのファイルを読み込む」コードを書いたわけです。

まず下準備として、airのインストーラーの設定で

こんな感じで、あらかじめ用意したdefaultSkins.swfというファイルを追加します。

ディレクトリの操作では、filesystemパッケージのfileクラスを使用します。
ではソースをば、

import flash.filesystem.*;
import flash.net.FileFilter;
/*
アプリケーションがインストールされてるフォルダ（アプリケーションディレクトリ）の"defaultSkins.swf"というファイルをアプリケーションのデータ用フォルダ（アプリケーションストレージディレクトリ）にコピーして利用します。

まずアプリケーションストレージディレクトリに"defaultSkins.swf"が存在するかどうかを調べ
無ければコピー、あればコピーせずに"defaultSkins.swf"を読み込み画面に表示します。
*/

//ファイル名
var skinFileName:String = "defaultSkins.swf";

//アプリケーションディレクトリのパスです。
var appDir:File = File.applicationDirectory;

//アプリケーションストレージディレクトリのパスです。
var appDb:File = File.applicationStorageDirectory;

//resolvePath()によって、新しいディレクトリパスを作ります。
//下記コードだと、「アプリケーションディレクトリ\defaultSkins.swf」となります。
var defaultSkin:File = appDir.resolvePath(skinFileName);

//下記コードだと「アプリケーションストレージディレクトリ\defaultSkins.swf」となります。
//ここでは、実際にそのファイルがあるかどうかは問題になりません。
var skinsPath:File = appDb.resolvePath(skinFileName);

file_txt.appendText("\n作成日時" + defaultSkin.creationDate);
file_txt.appendText("\n更新日時" + defaultSkin.modificationDate);

file_txt.appendText("\n" + skinsPath.nativePath);

//「アプリケーションストレージディレクトリ\defaultSkins.swf」が存在するかどうかを調べます。
//存在しなければ、copyToAsync()メソッドを利用して、ファイルをコピーします。
if(skinsPath.exists){
    file_txt.appendText("\ndefaultSkinsは存在します。");
    file_txt.appendText("\n作成日時" + skinsPath.creationDate);
    file_txt.appendText("\n更新日時" + skinsPath.modificationDate);
    setPanel();
}else{
    file_txt.appendText("\ndefaultSkinsは存在しません。\n作成します。");
    defaultSkin.copyToAsync(skinsPath , true);
}

defaultSkin.addEventListener(Event.COMPLETE , completedFunc);

function completedFunc(event:Event):void{
    file_txt.appendText("\nコピーしました。");
    var fileList:Array = new Array();
    fileList = appDb.getDirectoryListing();
   
    var count:int = fileList.length;
   
    for(var i:int = 0 ; i < count ; i++){
        file_txt.appendText("\n" + fileList[i].nativePath);
    }
    setPanel();
}

function setPanel():void{
    var skinAdress:URLRequest = new URLRequest(skinsPath.url);
    var loader:Loader = new Loader();
   
    loader.load(skinAdress);
    stage.addChild(loader);
   
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE , loadComp);
   
    function loadComp(event:Event):void{
        var tmp:MovieClip;
       
        tmp = event.target.content;
        tmp.gotoAndStop("昼");
    }
}

ポイントをいくつか
まず

var appDir:File = File.applicationDirectory;
var appDb:File = File.applicationStorageDirectory;

で「アプリケーションストレージディレクトリ」と「アプリケーションディレクトリ」の参照を取得します。
appDir.nativePath;
と記述すると、OSネイティブなディレクトリパスを取得できます。
例えば、Vistaの64Bitだと「C:\Program Files (x86)\dir」こうなるでしょう。
appDir.url;
と記述すると、「app:/」こうなります。ちなみに、ストレージディレクトリは「「app-storage:/」です。

つぎに
var defaultSkin:File = appDir.resolvePath(skinFileName);
resolvePathで、ディレクトリを移動しますので、defaultSkinのパスは「app:/defaultSkins.swf」となります。
nativePathは「C:\Program Files (x86)\dir\defaultSkins.swf」となるでしょうね。

ちなみにその下の
var skinsPath:File = appDb.resolvePath(skinFileName);
この行ですが、実際に「app-storage:/defaultSkins.swf」は、初回の起動時には存在しません。
でも、上記のコードはエラーになりません

resolvePathでは、実際にそのディレクトリやファイルが存在するかどうかは関係なありません。
そのファイルが存在するかどうかどうかは、Fileクラスのプロパティで取得できます。
その部分がこれです。
if(skinsPath.exists){
existsプロパティは、実際にそのファイル・ディレクトリが存在するかどうかを調べます。
ここでは、existsプロパティがtrue（ファイルが存在する）場合、直ちに読み込み処理をします。
無ければ、
defaultSkin.copyToAsync(skinsPath , true);
copyToAsyncメソッドで、defaultSkin（アプリケーションディレクトリのファイル）をskinsPathに（アプリケーションストレージディレクトリの、実際は存在しないファイル名）コピーし、終了したら読み込みます。

あとは、読み込み処理はloaderクラスを利用するんで、パスをURLRequestクラスのインスタンスにしなきゃいけなんで、Fileクラスのurlプロパティを使って、読み込みます。

てな訳で、アプリケーションの設定ファイルとか、後々追加更新するけれど、ユーザーに任意に操作させたくないなぁってファイルは、applicationStorageDirectoryを使って、このコードみたく、初回起動時にapplicationDirectoryからコピーするようにすると、なんだかアプリケーションみたいだね。

http://studio-ensyu.com/life-style/2008/09/as3swf.html

上の記事で、リンケージに関してちょろと説明ましたが・・・

例えばAS2.0で

var test_mc:MovieClip = _root.attachMovie("link" + id , "MC" + count++ , _root.getNextHighestDepth());

とか書きたい時ってどうすんの？
って話です。

まぁ手っ取り早くサンプルを。

>>Flaファイルをダウンロード

こんな感じで、画面上に、リンケージ設定させたいくつかのシンボルを、ランダムに配置するためには、文字列からクラス名を設定してやる必要があるんですが、さてさて、AS3.0ではどう書くのか・・・？

こう書きます。

import flash.utils.getDefinitionByName;

var className:String = "link" + id;
var ClassReference:Class = getDefinitionByName(className) as Class;

getDefinitionByName(className) as Class;
のclassNameに文字列で引数を渡すと、文字列をObjectに変換してくれるみたいです。
ただし、Objectのまんまだと、Classにならないんで、as Classでキャスト（の様な事）をします。
as Classを記述しないと「1118: 静的型 Object の値が、関連しない可能性が高い型 Class に暗黙で型変換されています。」というエラーを出すんで、明示的にキャストしてあげた方がいいでしょうねぇ（パブリッシュ設定でStrictモードのチェックを外すと、エラーは出ないんですけどね）。

あとはコレを画面に配置するには

var imgObj = new ClassReference();
stage.addChild (imgObj);

としてあげればOK。

んで、サンプルのソースは

//Tweenエフェクト用
import fl.transitions.Tween;
import fl.transitions.TweenEvent;
import fl.transitions.easing.*;

//文字列からクラスを生成するために必要。
import flash.utils.getDefinitionByName;

//リンケージのシンボルを、50ミリ秒ごとに生成
var ID:int = setInterval(intervalFunction , 50);

//生成のための関数
function intervalFunction(){
    //ステージサイズから、生成位置をランダムに生成。stage.widthとかだと、ステージに何も配置されてないと0になってしまうため即値を入れてます。
    var X:Number = Math.random() * 550;
    var Y:Number = Math.random() * 400;
    
    //2つのリンケージからランダムにどちらかのシンボルを指定。
    var id = Math.round(Math.random() * 1);
    var className:String = "link" + id;//ランダムに「link0」と「link1」が生成される。
    var ClassReference:Class = getDefinitionByName(className) as Class;
    
    //配置する。
    var imgObj = new ClassReference();
    stage.addChild (imgObj);
    
    imgObj.x = X;
    imgObj.y = Y;
}

    //生成したシンボルに、再生が終わった後に消す処理を登録。
    imgObj.addEventListener("testEvent" , Func);
}

//消す処理。
function Func(evt:Event){
    var target:Object = evt.target;
    var myTween:Tween = new Tween(target , "alpha" , Regular.easeOut , 1 , 0.2 , 0.2 , true);
    
    setTimeout(finish , 250 , target);
    function finish(){
        stage.removeChild(DisplayObject(arguments[0]));
    }
}

こうなってます。

ちなみに、生成されるシンボル自体は単なるシェイプトゥイーンするだけですが、最終フレームに

stop();
this.dispatchEvent(new Event("testEvent"));

と、記述し、「testEvent」という名前でイベントを送出してます。
すると、
imgObj.addEventListener("testEvent" , Func);
のように、「testEvent」を受け取ることが出来るわけです。
ただ、この辺は、AS2.0の流用なんで、ちょっと怪しい。 EventDispatcher()に関しては、もちょっと調べたらまたエントリー上げます。

//------------------------------------- 2009/2/26日追記 -------------------------------------//

どうやら、addEventListenerメソッドが受け取る第一引数はString型で、イベントタイプの定数もString型のようなので、これでいいみたい。
http://livedocs.adobe.com/flex/2_jp/langref/flash/events/Event.html
さらに言うと、Eventクラスのコンストラクタの第一引数もString型で、つまりは
dispatchEvent(new Event(MouseEvent.CLICK));とか書けば、強制的にクリックイベント送出できたりします。
AS2.0時代のsample_btn.onRelease();で、コードからマウスイベントを強制的に呼び出したみたいに。